esqlOC -static testsql.sqb

       IDENTIFICATION DIVISION.
       PROGRAM-ID. TESTSQL.
       ENVIRONMENT DIVISION.
       CONFIGURATION SECTION.
       DATA DIVISION.
       WORKING-STORAGE SECTION.
      *--------------------------------------------------*
      *   CREATE TABLE MYCONTACTS (
      *                FIRSTNAME CHAR(20) NOT NULL,
      *                LASTNAME  CHAR(20) NOT NULL,
      *                TELEPHONE CHAR(20) NOT NULL,
      *                EMAILADDR CHAR(80) NOT NULL )
      *--------------------------------------------------*
           EXEC SQL BEGIN DECLARE SECTION END-EXEC.

       01  HOSTVARS.
           05 DBNAME               PIC X(08) VALUE 'MYTESTDB'.
           05 FIRSTNAME            PIC X(20) VALUE SPACE.
           05 LASTNAME             PIC X(20) VALUE SPACE.
           05 TELEPHONE            PIC X(20) VALUE SPACE.
           05 EMAILADDR            PIC X(80) VALUE SPACE.

           EXEC SQL END DECLARE SECTION END-EXEC.
           EXEC SQL DECLARE C1 CURSOR FOR
                      SELECT FIRSTNAME,
                             LASTNAME,
                             TELEPHONE,
                             EMAILADDR
                        FROM MYCONTACTS
                    ORDER BY LASTNAME ASC,
                             FIRSTNAME ASC
           END-EXEC.
           EXEC SQL INCLUDE SQLCA       END-EXEC.

       PROCEDURE DIVISION.
       MAIN SECTION.

           PERFORM SQL-CONNECT
           PERFORM LIST-CONTACTS
           PERFORM SQL-DISCONNECT

           GOBACK
           .
      *--------------------------------------------------*
      * LIST THE CONTACTS FROM THE SQL TABLE CONTACTS
      *--------------------------------------------------*
       LIST-CONTACTS SECTION.

           EXEC SQL OPEN C1 END-EXEC.
           PERFORM SQLSTATE-CHECK

           PERFORM UNTIL SQLSTATE NOT = '00000'
                   EXEC SQL FETCH C1 INTO
                               :FIRSTNAME,
                               :LASTNAME,
                               :TELEPHONE,
                               :EMAILADDR
                   END-EXEC
                   IF SQLSTATE = '00000'
                      DISPLAY FIRSTNAME, LASTNAME, TELEPHONE, EMAILADDR
                   END-IF
           END-PERFORM

           EXEC SQL CLOSE C1 END-EXEC.
           PERFORM SQLSTATE-CHECK
           .
      *--------------------------------------------------*
      * CONNECT TO THE DATABASE
      *--------------------------------------------------*
       SQL-CONNECT SECTION.

           EXEC SQL CONNECT TO :DBNAME END-EXEC.
           PERFORM SQLSTATE-CHECK
           .

      *--------------------------------------------------*
      * DISCONNECT FROM THE DATABASE
      *--------------------------------------------------*
       SQL-DISCONNECT SECTION.

           EXEC SQL CONNECT RESET END-EXEC.
           PERFORM SQLSTATE-CHECK
           .

      *--------------------------------------------------*
      * CHECK SQLSTATE AND DISPLAY ERRORS IF ANY
      *--------------------------------------------------*
       SQLSTATE-CHECK SECTION.
           IF SQLSTATE NOT = '00000' AND SQLSTATE NOT = '02000'
                      DISPLAY 'SQLSTATE='  SQLSTATE,
                              ', SQLCODE=' SQLCODE
              IF SQLERRML > 0
                 DISPLAY 'SQL Error message:' SQLERRMC(1:SQLERRML)
              END-IF
           END-IF
           .